home *** CD-ROM | disk | FTP | other *** search
/ SGI Freeware 1999 August / SGI Freeware 1999 August.iso / dist / fw_hylafax.idb / usr / freeware / sbin / recvstats.z / recvstats
Encoding:
Text File  |  1999-07-16  |  9.0 KB  |  361 lines
  1. #! /bin/sh
  2. #    $Id: recvstats.sh.in,v 1.25 1996/06/24 03:06:25 sam Rel $
  3. #
  4. # HylaFAX Facsimile Software
  5. #
  6. # Copyright (c) 1990-1996 Sam Leffler
  7. # Copyright (c) 1991-1996 Silicon Graphics, Inc.
  8. # HylaFAX is a trademark of Silicon Graphics
  9. # 
  10. # Permission to use, copy, modify, distribute, and sell this software and 
  11. # its documentation for any purpose is hereby granted without fee, provided
  12. # that (i) the above copyright notices and this permission notice appear in
  13. # all copies of the software and related documentation, and (ii) the names of
  14. # Sam Leffler and Silicon Graphics may not be used in any advertising or
  15. # publicity relating to the software without the specific, prior written
  16. # permission of Sam Leffler and Silicon Graphics.
  17. # 
  18. # THE SOFTWARE IS PROVIDED "AS-IS" AND WITHOUT WARRANTY OF ANY KIND, 
  19. # EXPRESS, IMPLIED OR OTHERWISE, INCLUDING WITHOUT LIMITATION, ANY 
  20. # WARRANTY OF MERCHANTABILITY OR FITNESS FOR A PARTICULAR PURPOSE.  
  21. # 
  22. # IN NO EVENT SHALL SAM LEFFLER OR SILICON GRAPHICS BE LIABLE FOR
  23. # ANY SPECIAL, INCIDENTAL, INDIRECT OR CONSEQUENTIAL DAMAGES OF ANY KIND,
  24. # OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS,
  25. # WHETHER OR NOT ADVISED OF THE POSSIBILITY OF DAMAGE, AND ON ANY THEORY OF 
  26. # LIABILITY, ARISING OUT OF OR IN CONNECTION WITH THE USE OR PERFORMANCE 
  27. # OF THIS SOFTWARE.
  28. #
  29.  
  30. #
  31. # Print Statistics about Received Facsimile.
  32. #
  33. SPOOL=/usr/freeware/var/spool/fax
  34.  
  35. test -f $SPOOL/etc/setup.cache || {
  36.     cat<<EOF
  37.  
  38. FATAL ERROR: $SPOOL/etc/setup.cache is missing!
  39.  
  40. The file $SPOOL/etc/setup.cache is not present.  This
  41. probably means the machine has not been setup using the faxsetup(1M)
  42. command.  Read the documentation on setting up HylaFAX before you
  43. startup a server system.
  44.  
  45. EOF
  46.     exit 1
  47. }
  48. . $SPOOL/etc/setup.cache
  49.  
  50. FILES=
  51. SORTKEY=-sender                # default is to sort by sender
  52. TODAY="`date +'%D %H:%M'`"
  53. AGE="360"                # report statistics for last year
  54. SINCE=
  55.  
  56. while [ x"$1" != x"" ] ; do
  57.     case $1 in
  58.     -send*|-csi|-dest*|-speed|-rate|-format)
  59.         SORTKEY=$1;;
  60.     -age)   shift; AGE=$1;;
  61.     -since) shift; SINCE=$1;;
  62.     -*)        echo "Usage: $0 [-sortkey] [-age days] [-since date] [files]"
  63.         exit 1
  64.         ;;
  65.     *)        FILES="$FILES $1";;
  66.     esac
  67.     shift
  68. done
  69. if [ -z "$FILES" ]; then
  70.     FILES=$SPOOL/etc/xferlog
  71. fi
  72.  
  73. #
  74. # Construct awk rules to collect information according
  75. # to the desired sort key.  There are multiple rules for
  76. # dealing with the different formats that have existed
  77. # over time.
  78. #
  79. case $SORTKEY in
  80. -send*|-csi)
  81.     AWKRULES='
  82.     $2 == "RECV" && NF == 9  { acct($3, $7, $8, $5, $6, $9); }
  83.     $2 == "RECV" && NF == 11 { acct($6, $9, $10, $7, $8, $11); }
  84.     $2 == "RECV" && NF == 12 { acct($7, $10, $11, $8, $9, $12); }
  85.     $2 == "RECV" && NF == 13 { acct($9, $11, $12, getBR($10), getDF($10), $13); }
  86.     $2 == "RECV" && NF == 14 { acct($9, $11, $13, getBR($10), getDF($10), $14); }
  87.     '
  88.     ;;
  89. -dest*)
  90.     AWKRULES='
  91.     $2 == "RECV" && NF == 9  { acct($4, $7, $8, $5, $6, $9); }
  92.     $2 == "RECV" && NF == 11 { acct($5, $9, $10, $7, $8, $11); }
  93.     $2 == "RECV" && NF == 12 { acct($6, $10, $11, $8, $9, $12); }
  94.     $2 == "RECV" && NF == 14 { acct($8, $11, $13, getBR($10), getDF($10), $14); }
  95.     '
  96.     ;;
  97. -speed|-rate)
  98.     AWKRULES='
  99.     $2 == "RECV" && NF == 9  { acct($5, $7, $8, $5, $6, $9); }
  100.     $2 == "RECV" && NF == 11 { acct($7, $9, $10, $7, $8, $11); }
  101.     $2 == "RECV" && NF == 12 { acct($8, $10, $11, $8, $9, $12); }
  102.     $2 == "RECV" && NF == 13 { acct(getBR($10), $11, $12, getBR($10), getDF($10), $13); }
  103.     $2 == "RECV" && NF == 14 { acct(getBR($10), $11, $13, getBR($10), getDF($10), $14); }
  104.     '
  105.     ;;
  106. -format)
  107.     AWKRULES='
  108.     $2 == "RECV" && NF == 9  { acct($6, $7, $8, $5, $6, $9); }
  109.     $2 == "RECV" && NF == 11 { acct($8, $9, $10, $7, $8, $11); }
  110.     $2 == "RECV" && NF == 12 { acct($9, $10, $11, $8, $9, $12); }
  111.     $2 == "RECV" && NF == 13 { acct(getDF($10), $11, $12, getBR($10), getDF($10), $13); }
  112.     $2 == "RECV" && NF == 14 { acct(getDF($10), $11, $13, getBR($10), getDF($10), $14); }
  113.     '
  114.     ;;
  115. esac
  116.  
  117. #
  118. # Generate an awk program to process the statistics file.
  119. #
  120. tmpAwk=/tmp/xfer$$
  121. trap "rm -f $tmpAwk; exit 1" 0 1 2 15
  122.  
  123. ($CAT<<'EOF'
  124. #
  125. # Setup date conversion data structures.
  126. #
  127. function setupDateTimeStuff()
  128. {
  129.     daysInMonth[ 0] = 31; daysInMonth[ 1] = 28; daysInMonth[ 2] = 31;
  130.     daysInMonth[ 3] = 30; daysInMonth[ 4] = 31; daysInMonth[ 5] = 30;
  131.     daysInMonth[ 6] = 31; daysInMonth[ 7] = 31; daysInMonth[ 8] = 30;
  132.     daysInMonth[ 9] = 31; daysInMonth[10] = 30; daysInMonth[11] = 31;
  133.  
  134.     FULLDAY = 24 * 60 * 60;
  135. }
  136.  
  137. #
  138. # Convert hh:mm:ss to seconds.
  139. #
  140. function cvtTime(s)
  141. {
  142.     t = i = 0;
  143.     for (n = split(s, a, ":"); i++ < n; )
  144.     t = t*60 + a[i];
  145.     return t;
  146. }
  147.  
  148. #
  149. # Convert MM/DD/YY hh:mm to seconds.
  150. # NB: this does not deal with leap years.
  151. #
  152. function cvtDateTime(s)
  153. {
  154.     yday = substr(s,7,2)*365 + substr(s,4,2) - 1;
  155.     mon = substr(s,0,2) + 0;
  156.     for (i = 0; i < mon; i++)
  157.     yday += daysInMonth[i];
  158.     return yday*FULLDAY + cvtTime(substr(s,10) ":00");
  159. }
  160.  
  161. function setupDigits()
  162. {
  163.   digits[0] = "0"; digits[1] = "1"; digits[2] = "2";
  164.   digits[3] = "3"; digits[4] = "4"; digits[5] = "5";
  165.   digits[6] = "6"; digits[7] = "7"; digits[8] = "8";
  166.   digits[9] = "9";
  167. }
  168.  
  169. #
  170. # Format seconds as hh:mm:ss.
  171. #
  172. function fmtTime(t)
  173. {
  174.     v = int(t/3600);
  175.     result = "";
  176.     if (v > 0) {
  177.     if (v >= 10)
  178.         result = digits[int(v/10)];
  179.     result = result digits[int(v%10)] ":";
  180.     t -= v*3600;
  181.     }
  182.     v = int(t/60);
  183.     if (v >= 10 || result != "")
  184.     result = result digits[int(v/10)];
  185.     result = result digits[int(v%10)];
  186.     t -= v*60;
  187.     return (result ":" digits[int(t/10)] digits[int(t%10)]);
  188. }
  189.  
  190. #
  191. # Setup map for histogram calculations
  192. # and indexed table for decoding params.
  193. #
  194. function setupMaps(s, map, names)
  195. {
  196.     n = split(s, a, ":");
  197.     for (i = 1; i <= n; i++) {
  198.     map[a[i]] = i;
  199.     names[i-1] = a[i];
  200.     }
  201. }
  202.  
  203. #
  204. # Add pages to a histogram.
  205. #
  206. function addToMap(key, ix, pages, map)
  207. {
  208.     if (key == "") {
  209.     for (i in map)
  210.         key = key ":";
  211.     }
  212.     n = split(key, a, ":");
  213.     a[map[ix]] += pages;
  214.     t = a[1];
  215.     for (i = 2; i <= n; i++)
  216.       t = t ":" a[i];
  217.     return t;
  218. }
  219.  
  220. #
  221. # Return the name of the item with the
  222. # largest number of accumulated pages.
  223. #
  224. function bestInMap(totals, map)
  225. {
  226.    n = split(totals, a, ":");
  227.    imax = 1; max = -1;
  228.    for (j = 1; j <= n; j++)
  229.        if (a[j] > max) {
  230.        max = a[j];
  231.        imax = j;
  232.        }
  233.    split(map, a, ":");
  234.    return a[imax];
  235. }
  236.  
  237. #
  238. # Sort array a[l..r]
  239. #
  240. function qsort(a, l, r) {
  241.     i = l;
  242.     k = r+1;
  243.     item = a[l];
  244.     for (;;) {
  245.     while (i < r) {
  246.             i++;
  247.         if (a[i] >= item)
  248.         break;
  249.         }
  250.     while (k > l) {
  251.             k--;
  252.         if (a[k] <= item)
  253.         break;
  254.         }
  255.         if (i >= k)
  256.         break;
  257.     t = a[i]; a[i] = a[k]; a[k] = t;
  258.     }
  259.     t = a[l]; a[l] = a[k]; a[k] = t;
  260.     if (k != 0 && l < k-1)
  261.     qsort(a, l, k-1);
  262.     if (k+1 < r)
  263.     qsort(a, k+1, r);
  264. }
  265.  
  266. function getBR(params)
  267. {
  268.     return brNames[int(int(params) / 2) % 8];
  269. }
  270.  
  271. function getDF(params)
  272. {
  273.     return dfNames[int(int(params) / 512) % 4];
  274. }
  275.  
  276. #
  277. # Accumulate a statistics record.
  278. #
  279. function acct(key, pages, time, br, df, status)
  280. {
  281.     if (cvtDateTime($1) < KEEP)
  282.     return;
  283.     gsub("\"", "", key);
  284.     gsub("^ +", "", key);
  285.     gsub(" +$", "", key);
  286.     recvpages[key] += pages;
  287.     if (pages == 0 && time > 60)
  288.     time = 0;
  289.     recvtime[key] += cvtTime(time);
  290.     gsub("\"", "", status);
  291.     if (status != "")
  292.     recverrs[key]++;
  293.     gsub("\"", "", br);
  294.     recvrate[key] = addToMap(recvrate[key], br, pages, rateMap);
  295.     gsub("\"", "", df);
  296.     recvdata[key] = addToMap(recvdata[key], df, pages, dataMap);
  297. }
  298.  
  299. #
  300. # Print a rule between the stats and the totals line.
  301. #
  302. function printRule(n, s)
  303. {
  304.     r = "";
  305.     while (n-- >= 0)
  306.     r = r s;
  307.     printf "%s\n", r;
  308. }
  309.  
  310. BEGIN        { FS="\t";
  311.           rates = "2400:4800:7200:9600:12000:14400";
  312.           setupMaps(rates, rateMap, brNames);
  313.           datas = "1-D MR:2-D MR:2-D Uncompressed Mode:2-D MMR";
  314.           setupMaps(datas, dataMap, dfNames);
  315.           setupDateTimeStuff();
  316.           if (SINCE == "")
  317.               KEEP = cvtDateTime(TODAY) - AGE*FULLDAY;
  318.           else
  319.               KEEP = cvtDateTime(SINCE);
  320.         }
  321. END        { OFS="\t"; setupDigits();
  322.           maxlen = 15;
  323.           nsorted = 0;
  324.           for (i in recvpages) {
  325.               l = length(i);
  326.               if (l > maxlen)
  327.             maxlen = l;
  328.               sorted[nsorted++] = i;
  329.           }
  330.           qsort(sorted, 0, nsorted-1);
  331.           fmt = "%-" maxlen "." maxlen "s";    # e.g. %-24.24s
  332.           printf fmt " %5s %8s %6s %4s %7s %7s\n",
  333.               "Sender", "Pages", "Time", "Pg/min",
  334.               "Errs", "TypRate", "TypData";
  335.           tpages = 0;
  336.           ttime = 0;
  337.           terrs = 0;
  338.           for (k = 0; k < nsorted; k++) {
  339.               i = sorted[k];
  340.               t = recvtime[i]/60; if (t == 0) t = 1;
  341.               n = recvpages[i]; if (n == 0) n = 1;
  342.               brate = best
  343.               printf fmt " %5d %8s %6.1f %4d %7d %7s\n",
  344.               i, recvpages[i], fmtTime(recvtime[i]),
  345.               recvpages[i] / t, recverrs[i],
  346.               bestInMap(recvrate[i], rates),
  347.               bestInMap(recvdata[i], datas);
  348.             tpages += recvpages[i];
  349.             ttime += recvtime[i];
  350.             terrs += recverrs[i];
  351.           }
  352.           printRule(maxlen+1+5+1+8+6+1+4+1+7+1+7, "-");
  353.           t = ttime/60; if (t == 0) t = 1;
  354.           printf fmt " %5d %8s %6.1f %4d\n",
  355.               "Total", tpages, fmtTime(ttime), tpages/t, terrs;
  356.         }
  357. EOF
  358. echo "$AWKRULES"
  359. )>$tmpAwk
  360. $AWK -f $tmpAwk -v TODAY="$TODAY" -v AGE="$AGE" -v SINCE="$SINCE" $FILES
  361.